Arduino一個好用的計時器程式庫

這篇要介紹一個好用的Arduino計時器（Timer）程式庫，由Dr. Monk所開發，由Jack Christensen稍加修改後放在github上。

下載並解壓縮後，把目錄改名成Timer，搬移到Arduino軟體開發環境的sketchbook目錄的libraries子目錄下，你可以從File-Preferences-Sketchbook location:查到sketchbook目錄在哪，若裡面沒有libraries這個子目錄，請自行建立，然後把計時器程式庫整個Timer目錄搬進去。

需要重新開啟Arduino軟體開發環境，它才知道你新安裝的程式庫。

先舉個例子，假設要閃爍一個LED，點亮1秒，熄滅1秒，不斷循環，應該很簡單（這通常會是學習Arduino的第一支程式），程式碼如下：

假設Arduino腳位2接到LED的長腳（中間串接220 ohm電阻），短腳接地。
void setup() {               
  pinMode(2, OUTPUT);    
}

void loop() {
  digitalWrite(2, HIGH);
  delay(1000);
  digitalWrite(2, LOW);
  delay(1000);
}

好，那接下來，如果腳位3、4、5也都接了LED，我們想要讓每個LED以不同頻率閃爍，那該怎麼寫呢。

unsigned long previous_time;

void setup() {               
  pinMode(2, OUTPUT);
  pinMode(3, OUTPUT);
  pinMode(4, OUTPUT);
  pinMode(5, OUTPUT);
 
  digitalWrite(2, HIGH);
  digitalWrite(3, HIGH);
  digitalWrite(4, HIGH);
  digitalWrite(5, HIGH);
 
  previous_time = millis();
}

void update2(unsigned long time_passed){
  static unsigned long time = 0;
  time += time_passed;
  if((time / 200) % 2 == 0){ // 腳位2的LED明滅頻率為0.2秒
    digitalWrite(2, HIGH);
  }
  else{
    digitalWrite(2, LOW);
  }
}

void update3(unsigned long time_passed){
  static unsigned long time = 0;
  time += time_passed;
  if((time / 300) % 2 == 0){ // 腳位3的LED明滅頻率為0.3秒
    digitalWrite(3, HIGH);
  }
  else{
    digitalWrite(3, LOW);
  }
}

void update4(unsigned long time_passed){
  static unsigned long time = 0;
  time += time_passed;
  if((time / 400) % 2 == 0){ // 腳位4的LED明滅頻率為0.4秒
    digitalWrite(4, HIGH);
  }
  else{
    digitalWrite(4, LOW);
  }
}

void update5(unsigned long time_passed){
  static unsigned long time = 0;
  time += time_passed;
  if((time / 500) % 2 == 0){ // 腳位5的LED明滅頻率為0.5秒
    digitalWrite(5, HIGH);
  }
  else{
    digitalWrite(5, LOW);
  }
}

void loop() {
  unsigned long current_time = millis();
  unsigned long time_passed;

  if(current_time > previous_time ){
    time_passed = current_time - previous_time;
  }
  else{
    time_passed = ULONG_MAX - previous_time + current_time;
  }

  if(time_passed >= 100){
    update2(time_passed);
    update3(time_passed);
    update4(time_passed);
    update5(time_passed);
    previous_time = current_time;
  }
}

每次在loop裡，檢查距離上次更新是否經過了100ms（0.1秒），若是，呼叫update2、update3、update4、update5四個函式，分別負責更新腳位2、3、4、5的狀態。

你可以看得出來，有越多東西要處理，程式就會變得越複雜。若是有Timer計時器程式庫的話，就會變得簡單許多。

改用計時器後的程式碼如下：
// 首先匯入程式庫標頭檔Timer.h
#include <Timer.h>

// 用四個計時器控制四個LED
Timer t2;
Timer t3;
Timer t4;
Timer t5;

void setup() {
  pinMode(2, OUTPUT); // 腳位設定為輸出模式
  pinMode(3, OUTPUT);
  pinMode(4, OUTPUT);
  pinMode(5, OUTPUT);
 
  t2.oscillate(2, 200, HIGH); // 以oscillate設定每幾毫秒切換一次狀態
  t3.oscillate(3, 300, HIGH); // 第一個參數：哪個腳位
  t4.oscillate(4, 400, HIGH); // 第二個參數：幾毫秒
  t5.oscillate(5, 500, HIGH); // 第三個參數：初始狀態
}

void loop() {
  // 在loop裡，呼叫每個計時器的update，它才能運作更新狀態
  t2.update();
  t3.update();
  t4.update();
  t5.update();
}

如何，是不是簡單許多、合理許多了呢。

還有個every方法，每經過一段時間，就呼叫某回呼函式。範例：
#include <Timer.h>

Timer tcb;

void writeToSerial(){
  static  unsigned long count = 0;
  Serial.println(count); // 從0開始輸出，每次加1
  count++;
}

void setup() {
  Serial.begin(115200);
  tcb.every(1000, writeToSerial); // 每經過1000毫秒，就會呼叫writeToSerial
}

void loop() {
  tcb.update();
}

其他功能還有after（經過一段時間後，呼叫某函式，只呼叫一次）、pulse（經過一段時間後，切換某腳位的狀態，只一次）、stop（取消某個計時器事件）、等等，可看看原文章的最下面，有API解說。

PS 另外有個計時器程式庫叫Metro，不過我覺得比較不好用。