Arduino Yún：Bridge程式庫入門（Console與Process）

Yún除了有一顆微控制器ATmega32U4（跟Leonardo相同），還有一顆Atheros AR9331，運行Linux發行套件Linino（以OpenWRT為基礎修改而成），這顆晶片連接有線網路（Ethernet）介面、無線網路（WiFi）介面、板子上的USB A埠（主方）與micro SD記憶卡插槽。

當我們撰寫ATmega32U4的草稿碼時，可透過Bridge程式庫來跟Atheros AR9331的Linino溝通，使用各種功能。請看官方網站提供的架構示意圖。

Bridge程式庫裡有許多類別，分別對應各種功能包括Bridge、Process、Console、FileIO、Mailbox、HttpClient、YunClient與YunServer。其原始碼都在Arduino軟體開發環境安裝目錄\libraries\Bridge底下。

接下來就嘗試一下Console與Process，底下的程式碼大部分都是從Arduino官方網站與軟體開發環境提供的範例修改而來。

首先是Console，顧名思義就是類似主控台、終端機之類的功能，跟以前的序列埠很像，但現在可經由WiFi無線登入。

底下這支程式會從Console接收資料，若收到字元H就點亮板子上內建的LED，若收到字元L就熄滅。

#include <Console.h>
#define LED_PIN 13

void setup() {
  Bridge.begin(); // 啟動Bridge，其他類別都需要它
  Console.begin(); // 初始化Console

  while (!Console) // 等待開啟Console
    ;
  if(Console.connected()){
    Console.println("Console is connected");
  }
  Console.println("type H or L to turn pin 13 on or off");

  pinMode(LED_PIN, OUTPUT);
}
void loop() {
  if(Console.available() > 0){
    char b = Console.read();
    Console.println(b);
    if(b == 'H'){
      digitalWrite(LED_PIN, HIGH);
    }
    else if(b == 'L'){
      digitalWrite(LED_PIN, LOW);
    }
  }
}

Console類別用起來就跟Serial差不多。然後可從選單「工具-連接埠」選擇「Arduino at xxx.xxx.xxx.xx (Arduino Yún)」，此時開啟序列埠監控視窗的話，便可連接Yún的Console，畫面如下。

也可自己透過SSH登入取得Console，請把arduino.local換成你的Yún的IP位址。

$ ssh root@arduino.local
root@arduino.local's password:
...省略...

登入後下指令連接Console，如下：

root@Arduino:~# telnet localhost 6571
Console is connected
type H or L to turn pin 13 on or off

然後就可以輸入H或L控制LED亮滅。

然後是Process，可要求執行某程式或Linux指令，底下程式碼會執行uptime指令，得知系統開機後已經過多少時間，然後執行curl，取回以ASCII畫出來的Arduino logo。

#include <Process.h>

void setup() {
  Bridge.begin();
  Serial.begin(19200);
  while(!Serial)
    ;

  run_uptime();
  run_curl();
}
void loop() {
}
void run_curl() {
  Process p;
  p.begin("curl"); // 指令Linux指令
  p.addParameter("http://arduino.cc/asciilogo.txt"); // 加上參數
  p.run(); // 執行，這是阻斷式方法，執行結束後才會回傳

  while(p.available() > 0){ // 將指令執行結果送往序列埠監控視窗
    char c = p.read();
    Serial.print(c);
  }
  Serial.flush();
}
void run_uptime(){
  Process p;
  p.begin("uptime");
  p.run();

  while(p.available() > 0){
    char c = p.read();
    Serial.print(c);
  }
  Serial.flush();
}

其結果如下圖：

對Bridge程式庫有基本了解後，就可以開始玩玩其他更進階的類別，諸如YunServer、YunClient、HttpClient、MailBox、等等。


參考資料：

• Arduino官方文件的ArduinoYun與Bridge Library for Arduino Yún。
• Arduino官方部落格Hands on: the Arduino Yún’s Bridge。