Arduino練習：Simon Says請你跟我這樣做

我看了這篇在Instructables的文章Arduino Simon Says，這邊有他完成後的影片。

Simon Says這個遊戲是這麼玩的，有四個按鈕對應四個LED，程式會亂數點亮LED，你要記住順序，然後依序按下那四個按鈕，若對了就會發出成功的音效，錯了則發出失敗的音效，然後再繼續下一次。

電路很簡單，但程式落落長，讀別人的code很痛苦，所以我決定自己寫寫看。

首先練習一下Arduino板內建的上拉電阻（pullup resistor），如果你已經知道這是什麼，可以跳過。

Arduino板子上的數位腳位（digital pin），以pinMode()設定為INPUT模式時，若該腳位沒有連接到任何東西，那麼以digitalRead()讀取時，會讀到空氣、環境的值，也就是說是亂數，通常我們不希望如此，我們希望該腳位能有個明確的值，HIGH或LOW。之前的Arduino練習：以開關切換LED明滅狀態，也是如此，開關的一邊接到5V，另一邊則接地，這麼一來，不是HIGH就是LOW，不會讀到亂數。

接線如下：

從Arduino板的GND接到麵包板。 
Arduino腳位5接開關右上腳，開關左下腳接地。
Arduino腳位13接LED長腳，LED短腳接GND。



按下開關的話，開關左右兩邊連接在一起，所以腳位3會讀到LOW，而在不按下開關的情況，我們希望讀到HIGH，但是開關右下腳並沒有連接5V啊？可以利用Arduino板子內建的上拉電阻，以程式控制，如下：

void setup(){
    Serial.begin(115200);
    pinMode(13, OUTPUT); // LED，平常點亮，按下開關則熄滅
    pinMode(5, INPUT); // 接到開關
    digitalWrite(5, HIGH); // 開啟上拉電阻
}

void loop(){
    int status = digitalRead(5); // 讀取開關狀態
    digitalWrite(13, status); // 根據開關狀態控制LED明滅
    Serial.println(status);
}

其中，當腳位5設為INPUT模式時，可用digitalWrite(5, HIGH)開啟上拉電阻，如此一來，在平常時（不按下開關），就會讀到HIGH。

執行程式後，開啟序列埠監控視窗，平常會看到1，若按下開關，則為0。


好，接下來，要開始製作Simon Says。

電路圖（Fritzing格式）與程式原始碼，可在此下載。

完整的電路圖如下，接下來會一部份一部份慢慢接。


從Arduino板的GND接到麵包板。

先插上四個瞬時型開關，左下腳接地。右上腳，從左到右，接到腳位5、4、3、2。


然後，開關的左上腳接LED的短腳，LED的長腳接到100 ohm電阻。


然後，從左到右，電阻的另一腳，接到Arduino板的腳位11、10、9、8。


聲音的部份。從Arduino板的腳位A0接到1k ohm可變電阻的左腳，中腳接蜂鳴器的紅線，蜂鳴器的黑線接地。將以這個可變電阻調整音量。


程式碼，我將以功能區塊劃分說明。

#define TONE_PIN A0 // 定義蜂鳴器的腳位
#define NUMBER 4 // 共有四個LED、四個開關

// 定義開關與LED的腳位
const int switches[NUMBER] = {5, 4, 3, 2};
const int leds[NUMBER] = {11, 10, 9, 8};

// 定義各LED對應的音符頻率
const int notes[NUMBER] = {
    NOTE_C4, NOTE_D4, NOTE_E4,NOTE_F4,
};

// 將使用狀態機的概念，所以要定義各種狀態
typedef enum{
    STATE_START, // 重新開始遊戲
    STATE_QUESTION, // 閃爍LED，給出問題
    STATE_ANSWER, // 等待使用者按下開關，回答問題
    STATE_CORRECT, // 正確，播放恭喜的音效，重置
    STATE_WRONG, // 錯誤，播放可惜的音效，重置
    STATE_MAX,
} State;

// 定義播放音效的資料，詳細資料請看原始碼
Melody melodys[MELODY_MAX] = {
    {noteStart, noteDurationsStart, 13},
    {noteCorrect, noteDurationsCorrect, 6},
    {noteWrong, noteDurationsWrong, 8},
};

// 以tone()播放音效，這裡就不解說了。
// 用法請看Arduino練習：loudspeaker揚聲器。
void playtone(int *note, int *noteDurations, int num){
  for(int thisNote = 0; thisNote < num; thisNote++){
    int noteDuration = 3000 / noteDurations[thisNote];
    tone(TONE_PIN, note[thisNote], noteDuration);

    int pauseBetweenNotes = noteDuration * 1.30;
    delay(pauseBetweenNotes);
  }
}

// 這支程式裡有三種音效，開始遊戲、回答正確、回答錯誤
typedef enum{
    MELODY_START,
    MELODY_CORRECT,
    MELODY_WRONG,
    MELODY_MAX,
} Melody_Enum;
// 把playtone()包一層，用起來比較簡單
void playMelody(Melody_Enum me){
    playtone(melodys[me].note, melodys[me].duration, melodys[me].number);
}

// 初始化，開關的腳位，開啟上拉電阻，所以預設狀態會是HIGH，
// 之後讀取開關狀態時，若讀到LOW，代表按下按鍵
void setup(){
    for(int i = 0; i < NUMBER; i++){
        pinMode(switches[i], INPUT);
        digitalWrite(switches[i], HIGH);
       
        pinMode(leds[i], OUTPUT);
        digitalWrite(leds[i], LOW);
    }
   
    // 亂數，將以亂數製作問題
    randomSeed(analogRead(A1));
}

// 只播放一個音符的函式，秀出問題時可用，
// 使用者回答時也可用。
void playOneTone(int note, float delayScale){
    int noteDuration = 3000 / 8;
    tone(TONE_PIN, note, noteDuration);
   
    int pauseBetweenNotes = noteDuration * delayScale;
    delay(pauseBetweenNotes);

}

// 準備好問題後，放出音效、閃爍LED
void playQuestionsTone(){
    for(int i = 0; i < q_num; i++){
        digitalWrite(leds[questions[i]], HIGH);
        playOneTone(notes[questions[i]], 1.3);
        digitalWrite(leds[questions[i]], LOW);
    }
}

// 檢查問題跟使用者的回答是不是一樣
boolean check(){
    for(int i = 0; i < q_num; i++){
        if(questions[i] != answers[i]){
            return false;
        }
    }
    return true;
}

// 然後就是重頭戲了
void loop(){
    switch(state){ // 以state記錄目前狀態，根據狀態作事
        case STATE_START:{ // 開始遊戲，播放開始音效，進入問題狀態
            reset();
            playMelody(MELODY_START);
            state = STATE_QUESTION;
            break;
        }
       
        case STATE_QUESTION:{ // 問題狀態，以亂數製作問題
            questions = (int *)(malloc(sizeof(int) * q_num));
            answers = (int *)(malloc(sizeof(int) * q_num));
            for(int i = 0; i < q_num; i++){
                questions[i] = random(0, NUMBER);
            }
            answer_num = 0;
            playQuestionsTone(); // 顯示問題
            lastClickTime = millis(); // 記錄目前時間
            state = STATE_ANSWER;
            break;
        }
       
        case STATE_ANSWER:{
            // 看看使用者多久沒按開關了，超過10就宣布失敗
            const unsigned long nowTime = millis();
            if(nowTime >= lastClickTime + 10000UL){
                state = STATE_WRONG;
                break;
            }
           
            // 讀取每個開關的狀態
            for(int i = 0; i < NUMBER; i++){
                int ss = digitalRead(switches[i]);
                if(ss == LOW){
                    digitalWrite(leds[i], HIGH);
                    lastClickTime = nowTime;
                    answers[answer_num] = i; // 把使用者的輸入答案存起來
                    answer_num++;
                    playOneTone(notes[i], 1);
                    digitalWrite(leds[i], LOW);
                    delay(200);
                    break;
                }
               
            }
           
            if(answer_num >= q_num){ // 判斷是不是已經回答完了
                // 檢查回答正不正確
                state = check() ? STATE_CORRECT : STATE_WRONG;
            }
            break;
        }
       
        case STATE_CORRECT:{ // 回答正確，恭喜
            q_num++;
            playMelody(MELODY_CORRECT);
            delay(2000);
            state = STATE_START;
            break;
        }
       
        case STATE_WRONG:{ // 回答錯誤，可惜
            playMelody(MELODY_WRONG);
            delay(2000);
            state = STATE_START;
            break;
        }
       
        default:{
            state = STATE_START;
            break;
        }
    }
}

完成後的影片如下：



參考資料：

• Arduino官方文件，數位腳位（digital pins），裡頭說明上拉電阻（pullup resistor）。
• mpilchfamily的Arduino Simon Says。