Arduino練習：以開關切換LED明滅狀態

之前已經把Arduino的硬體與軟體安裝設定好、閃爍LED，然後寫程式透過序列埠輸出訊息到電腦上，這一篇是關於讀取開關（按鈕）的狀態，並以之切換LED的明滅。

電路圖（Fritzing格式）與程式原始碼，可在此下載。

讀取開關的狀態：

電路圖如下：

從Arduino板子上的5V腳位、GND腳位，接線到麵包板上。
瞬時型開關（momentary switch）的右上腳接到Arduino板子的腳位2，我們將以這個腳位讀取開關的狀態，開關的左下腳連接5V，開關的右下腳連接10k ohm電阻後接地。



當開關處於平常狀態時，右上腳與右下腳是接在一起的，但左右兩邊沒有連接，此時讀取開關的狀態，會讀到LOW低電壓。按下開關時，左右兩邊會接在一起，就會讀到HIGH高電壓。

程式碼如下：
void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
}

void loop(){
  int switchStatus = digitalRead(2);
  Serial.println(switchStatus);
}
首先在setup()裡，設定序列埠傳輸速度，然後以pinMode()設定腳位2的模式，這裡設為INPUT模式，以讀取開關的狀態。（後面將把另一個腳位設為OUTPUT模式，藉以控制LED的明滅。）

然後在loop()裡，以digitalRead()讀取腳位2的狀態，會讀到LOW或HIGH，代表開關的狀態。並輸出到序列埠。

開啟Tools-Serial Monitor可看到執行結果，開關平常狀態為0（LOW），按下後為1（HIGH），因為這是個瞬時型開關，放開手後會回到平常狀態。


在Arduino Uno板子上，有14個數位腳位（digital pin），標示著0、1、2、3、一直到13，這些腳位可以用pinMode()設定為INPUT模式或OUTPUT模式，然後可以用digitalRead()讀取電壓狀態LOW或HIGH，可用digitalWrite()函式設定電壓LOW或HIGH。

使用數位腳位進行讀取時，有一點要注意，以上面這個例子來說，如果沒有加上10k ohm電阻，那麼，當開關處於平常狀態，此時若讀取腳位2的話，或讀到環境雜訊（亂數，一下子是HIGH，一下子是LOW）。你可以把電阻拿掉，看看結果。當你看到LED亂閃時，可以檢查看看電路、開關、電阻是不是鬆了。

好，到這裡已經可以讀取開關的狀態了，接下來讓我們以之控制LED的明滅。

以開關控制LED明滅：

加裝一個LED，長腳插在13腳位，短腳插在GND，其餘跟之前一樣。

程式碼如下：
void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
  pinMode(13, OUTPUT);
}

void loop(){
  int switchStatus = digitalRead(2);
  digitalWrite(13, switchStatus);
  Serial.println(switchStatus);
}
以pinMode()將腳位13設為OUTPUT模式，然後，讀取到開關狀態後，以digitalWrite()更新LED的明滅。

平常時，LED滅掉，按下開關才會亮起來，但放開手後LED又會滅掉。

以開關切換LED明滅狀態：

讓我們繼續修改，我希望按一下開關可點亮LED，手放開後保持著明亮狀態，然後再按一下開關，LED才會滅掉，以此類推。

程式碼如下：
static int ledStatus;

void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
  pinMode(13, OUTPUT);
 
  ledStatus = LOW;
  digitalWrite(13, ledStatus);
}

void loop(){
  int switchStatus = digitalRead(2);
  if(switchStatus == HIGH){
    ledStatus = ledStatus == HIGH ? LOW : HIGH;
    digitalWrite(13, ledStatus);
  }
 
  Serial.println(ledStatus);
}
以全域靜態變數ledStatus記錄LED的明滅狀態。在loop()裡，若發現按下開關（switchStatus == HIGH），就切換LED的明滅。

聽起來很簡單，寫起來很直覺，可惜，實際動起來後，會很奇怪。點按開關後，有時LED會亮、有時不亮，很奇怪。

解決bounce：

這是因為，開關有所謂的bounce問題，我們人類按一下開關，感覺是切換一次，可是在微觀的電子元件裡，可能會造成好幾次的開、關狀態變換，而且，對人類來說，按一下開關不過是一瞬間的事情，但是這段時間裡，loop函式不知道已經被執行多少次了，也就是說，已經讀取好幾次腳位2的值。用底下程式碼可以更清楚問題所在。

static int ledStatus;

static int count = 0;

void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
  pinMode(13, OUTPUT);
 
  ledStatus = LOW;
  digitalWrite(13, ledStatus);
}

void loop(){
  int switchStatus = digitalRead(2);
  if(switchStatus == HIGH){
    ledStatus = ledStatus == HIGH ? LOW : HIGH;
    digitalWrite(13, ledStatus);
   
    count++;
  }
 
  Serial.println(ledStatus);
  Serial.println(count);
}
你會發現，按一下開關，count不只會往上加一，可能會好幾十、幾百。

那麼要怎麼解決bounce問題呢？那就要多寫一些程式碼了。

static int ledStatus;
static unsigned long lastDebounceTime;
#define DEBOUNCE_DELAY 200

void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
  pinMode(13, OUTPUT);
 
  ledStatus = LOW;
  digitalWrite(13, ledStatus);
}

void updateLed(){
  unsigned long currentTime = millis();
  if((currentTime - lastDebounceTime) > DEBOUNCE_DELAY){
    lastDebounceTime = currentTime;
  
    ledStatus = ledStatus == HIGH ? LOW : HIGH;
    digitalWrite(13, ledStatus);
    Serial.println(ledStatus);
  }
}

void loop(){
  int switchStatus = digitalRead(2);
 
  if(switchStatus == HIGH){
    updateLed();
  }
}
以全域靜態變數ledStatus記錄LED的明滅狀態。

每當執行loop()時，若腳位2處於HIGH狀態（開關被按下），就執行updateLed()函式。若腳位2處於LOW狀態，就不作事（LED狀態不變）。

在updateLed()裡，首先以Arduino內建函式millis()取得時間放在currentTime變數裡，這是Arduino板子開始執行程式後所經過的時間，單位為千分之一秒，回傳的型別是個unsigned long，所以最多大約是50天，超過後就會溢位回到0開始算。

全域靜態變數lastDebounceTime代表的是，上次切換LED狀態的時間。將currentTime目前時間，減去lastDebounceTime後，若大於DEBOUNCE_DELAY的話，代表距離上次切換LED狀態，已經經過一段夠久的時間了，所以繼續往下執行，先把currentTime存到lastDebounceTime（因為我們將要切換LED狀態了，把時間記錄下來），然後切換LED狀態（亮變滅、滅變亮）。

哇，成功啦，按一下開關，LED亮起，再按一下，LED滅掉，好耶。

如果你的情況仍不完美的話，請試試調整DEBOUNCE_DELAY的值，當我用50或100時，仍無法避免bounce，調到200才ok。你可以繼續往上調，但是，這個數值代表在那一段時間內，都無法切換LED狀態，譬如假設改成3000（三秒）的話，按下開關點亮LED後，這時怎麼按開關都沒反應，要經過三秒後，按下開關才能滅掉LED。

利用別人寫好的程式庫解決bounce：

好累喔，用開關切換LED，怎麼這麼累啊，還好，已經有人把解決bounce的程式寫好了，我們把程式庫拿來用即可。

有套Bounce library for Arduino，下載Bounce.zip，將解壓縮後的目錄，放到Arduino的Sketchbook目錄的子目錄libraries下。先以File-Preferences，查出Sketchbook目錄的路徑所在，底下若無libraries這個子目錄，請自行建立，然後把Bounce.zip解壓縮後的整個目錄放進去。

2014.03.01更新：原網址已經變成新版Bounce2，所以請到GitHub justjoheinz / Bounce下載這篇文章所使用的Bounce程式庫。

（Windows的Sketchbook目錄大概會位於C:\Documents and Settings\My Documents\Arduino，若是Mac，位於家目錄下的Documents/Arduino/，若是Linux，則是家目錄下的sketchbook目錄。）

然後重新啟動Arduino軟體開發環境。

要使用這套程式庫，請選Sketch-Import Library...-Bounce，匯入標頭檔#include "Bounce.h"。（如果在Sketch-Import Library...底下沒看到Bounce，代表你目錄放錯位置了。）

改寫後的程式如下：
#include <Bounce.h>

Bounce bouncer = Bounce(2, 50);
static int ledStatus = LOW;

void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
  pinMode(13, OUTPUT);
}

void loop(){
  if(bouncer.update() == true && bouncer.read() == HIGH) {
    ledStatus = ledStatus == HIGH ? LOW : HIGH;
    digitalWrite(13, ledStatus);
  }
}
首先建立Bounce物件，第一個參數是腳位，第二個參數是延遲時間。

然後，以update()更新腳位的狀態，若回傳true，代表腳位的狀態有變（從HIGH到LOW，或從LOW到HIGH）。

然後，以read()讀取更新後的腳位狀態。

在程式進行判斷，若腳位狀態有變（bouncer.update() == true），並且，腳位狀態為高電壓（bouncer.read() == HIGH），那麼就切換LED明滅。

成功啦。


以下為2012/08/25新增內容。

行為：開關處於平常狀態時，LED滅掉；手指按著開關時，LED亮起；但放開手指後LED就立刻滅掉，另外，按著開關超過5秒的話，LED也會滅掉。

修改後的程式碼如下：

#include <Bounce.h>

Bounce bouncer = Bounce(2, 50);
static int ledStatus = LOW;

void setup(){
  Serial.begin(115200);
  pinMode(2, INPUT);
  pinMode(13, OUTPUT);
  digitalWrite(13, ledStatus);
}

void loop(){

  bouncer.update();

  if(bouncer.read() == HIGH) {

    ledStatus = bouncer.duration() >= 5000 ? LOW : HIGH;

  }

  else{

    ledStatus = LOW;

  }

  digitalWrite(13, ledStatus);
}

每次進入loop時，就呼叫bouncer.update()更新開關讀取狀態，若開關狀態為HIGH（代表按下開關），繼續呼叫bouncer.duration()做判斷，此函式回傳的是該開關處於該狀態多長時間了，單位為千分之一秒，若超過5秒，就滅掉LED，若未足5秒，就點亮LED；若開關狀態為LOW（沒有按下開關），就滅掉LED。


參考資料：

• Arduino官方範例，Examples > Basics > Digital Read Serial，Examples > Digital > Button，Examples > Digital > Debounce。
• Arduino官方網站關於數位腳位（digital pin）的說明文件，函式pinMode()、digitalRead()、digitalWrite()的說明。
• 解決bounce的程式庫，Bounce library for Arduino。
• Cooper Maa的Arduino教學文章，Lab2 使用按鍵控制 LED 燈號。 
• sciguy14教學影片，Tutorial 10 for Arduino: Interrupts and Hardware Debouncing，以硬體RC線路搭配AVR晶片的中斷系統，解決bounce問題。