Arduino Yún：Bridge程式庫入門（YunServer與YunClient）

這一篇玩玩Bridge程式庫裡的YunServer與YunClient這兩個類別，程式碼主要都來自於Arduino官方文件Guide to the Arduino Yún。

我的Yún與開發主機位於同一個區域網路內，我的Arduino軟體開發環境是1.5.6-r2版。首先從瀏覽器登入Yún，開啟REST API存取權限為OPEN。

底下是範例程式碼，這支程式碼的功能是讓我們從別台電腦的瀏覽器控制Arduino的腳位。

#include <Bridge.h>
#include <YunServer.h>
#include <YunClient.h>

YunServer server; // 建立YunServer物件
void setup() {
  Serial.begin(19200);
  Bridge.begin(); // 啟動Bridge
  while(!Serial)
    ;
  server.listenOnLocalhost(); // 設定讓伺服器聆聽本地端IP位址的連線
  server.begin(); // 開始
}
void loop() {
  YunClient client = server.accept(); // 有連線進來了
  if(client){
    process(client); // 開始處理，分析API
    client.stop();
  }
  delay(50);
}
void process(YunClient client){
  String command = client.readStringUntil('/');
  if(command == "digital"){ // 數位輸入輸出
    digitalCommand(client);
  }
  else if(command == "analog"){ // 類比輸入輸出
    analogCommand(client);
  }
  else if(command == "mode"){ // 設定腳位模式
    modeCommand(client);
  }
}
void digitalCommand(YunClient client){
  int pin, value;
  pin = client.parseInt();
  if(client.read() == '/'){ // 數位輸出，設定為1（高電位）或0（低電位）
    value = client.parseInt();
    digitalWrite(pin, value);
    client.print("Pin ");
    client.print(pin);
    client.print(" set to ");
    client.println(value);
  }
  else{ // 數位輸入，讀取該腳位的值
    value = digitalRead(pin);
    client.print("Pin ");
    client.print(pin);
    client.print(" reads ");
    client.println(value);
  }
}
void analogCommand(YunClient client){
  int pin, value;
  pin = client.parseInt();
  if(client.read() == '/'){ // 類比輸出，設定PWM值為0~255
    value = client.parseInt();
    analogWrite(pin, value);
    client.print("Pin ");
    client.print(pin);
    client.print(" set to analog ");
    client.println(value);
  }
  else{ // 類比輸入，讀取該類比腳位的值
    value = analogRead(pin);
    client.print("Pin ");
    client.print(pin);
    client.print(" reads analog ");
    client.println(value);
  }
}
void modeCommand(YunClient client){
  int pin;
  pin = client.parseInt();
  if (client.read() != '/') {
    client.println("error");
    return;
  }
  String mode = client.readStringUntil('\r');
  if(mode == "input"){ // 設為輸入模式
    pinMode(pin, INPUT);
    client.print("Pin ");
    client.print(pin);
    client.print(" configured as INPUT.");
    return;
  }
  else if(mode == "output"){ // 設為輸出模式
    pinMode(pin, OUTPUT);
    client.print("Pin ");
    client.print(pin);
    client.print(" configured as OUTPUT.");
    return;
  }
  client.print("error: invalid mode ");
  client.print(mode);
}

然後從別台電腦的瀏覽器，輸入類似底下的網址，請把arduino.local換成你的Yún的IP位址。

把腳位13設為輸出模式：
http://arduino.local/arduino/mode/13/output
瀏覽器上會看到回應：
Pin 13 configured as OUTPUT.

把腳位13設為高電位，其連接的LED會亮起：
http://arduino.loca/arduino/digital/13/1
瀏覽器上會看到回應：
Pin 13 set to 1

把腳位13設為高電位，其連接的LED會熄滅：
http://arduino.loca/arduino/digital/13/0
瀏覽器上會看到回應：
Pin 13 set to 0

腳位3輸出PWM128：
http://arduino.loca/arduino/analog/3/128
瀏覽器上會看到回應： 
Pin 3 set to analog 128

讀取類比腳位A0（對應腳位編號18）的值：
http://arduino.loca/arduino/analog/18
瀏覽器上類似底下的回應：
Pin 18 reads analog 147

嗯，大概就這樣吧。


參考資料：

• Arduino官方文件，Guide to the Arduino Yún、YunServer類別與YunClient類別。