Arduino練習：紅外線傳送與接收

這篇的主角是紅外線（infrared、IR），俗稱紅外光，其波長在770nm（奈米）至1mm（毫米）之間，而人眼可感知的電磁波波長一般在400到700nm之間，所以紅外線屬於不可見光，在通訊、探測、醫療、軍事等方面有廣泛的用途。

請看看底下電磁波頻譜示意圖，可得知紅外線介於可見光（visible）與微波（microwave）之間。（圖片來源：維基百科）




 
這篇的重點是紅外線遠端遙控，家裡電視機、音響、錄影機、DVD播放器
的遙控器，便是利用紅外線傳輸，從遙控器端（紅外線發射器）透過紅外線通訊技術發出特定編碼，然後由電視機的紅外線接收器接收，進行解碼並執行相關功能，譬如開啟電視機的電源、加大或減少音量、切換頻道、等等。

我用的是Arduino Uno R3板子、Arduino軟體開發環境為1.0.4版。

所需電子零件：

• 紅外線接收器（Infrared Receiver），38kHz，例如TSOP38238、TSOP2438、TSOP4438、PNA4602、FM-6038TH2、FM-8038TM2-5DN。
• 紅外線發射器（Transmitter、Emitter或稱 IR LED)，發射波長為940nm。
• 100 ohm電阻。

為什麼是38kHz？這叫做載波頻率，因為生活周遭的物品都會散發出不定程度的紅外線，為了避免干擾，設計紅外線接收器時便讓它只對特定載波頻率有反應。不同廠牌的遙控器可能會使用不同的載波頻率，但38kHz最普遍。請注意，本篇使用38kHz的紅外線接收器，不一定可正確接收你家遙控器發出的紅外線訊號，需查詢該遙控器的規格，購買正確的紅外線接收器。

為什麼是940nm呢？我查詢了紅外線接收器的資料規格表後，其中註明了其最高峰波長為940nm，也就是最敏感的地方，所以我買了能發射波長940nm的紅外線發射器。其他常見的波長還有850nm，你也可以多買一個試試看。

底下是我買的零件，大約幾十元便可搞定。


紅外線接收器的腳位非常簡單，從腳位Vout讀取紅外線訊號，腳位GND接地，以腳位Vcc提供5V電源。注意：有些紅外線接收器的GND和Vcc腳位相反，還請查詢資料規格表（datasheet）以免接錯。


底下是接線圖，非常簡單。

紅外線接收器的Vout接Arduino的數位腳位2。

紅外線接收器的GND接Arduino的GND。

紅外線接收器的Vcc接Arduino的5V。


我使用Ken Shirriff開發撰寫的IRRemote這套Arduino程式庫，下載後解壓縮，將目錄改名為IRremote，然後整個放進sketchbook/libraries裡，重開Arduino軟體開發環境後，便可在Sketch-Import Library...裡看到它的蹤影。

每家廠商都有其一套專屬的紅外線通訊協定（protocol），知名的有NEC、SONY、Philips的RC5與RC6、Toshiba、Sharp、等等，這也就是為什麼這一家的遙控器不能控制那一家的電視機。還好IRRemote已經幫我們準備好了，一般常見的紅外線協定都有支援。

程式碼如下，也非常簡單，收到紅外線訊號後便輸出到序列埠。

#include <IRremote.h>

int RECV_PIN = 2; // 使用數位腳位2接收紅外線訊號
IRrecv irrecv(RECV_PIN); // 初始化紅外線訊號輸入
decode_results results; // 儲存訊號的結構

void setup()
{
  Serial.begin(115200);
  irrecv.blink13(true); // 設為true的話，當收到訊號時，腳位13的LED便會閃爍
  irrecv.enableIRIn(); // 啟動接收
}

void loop() {
  if (irrecv.decode(&results)) { // 接收紅外線訊號並解碼
    Serial.print("results value is "); // 輸出解碼後的資料
    Serial.print(results.value, HEX);
    Serial.print(", bits is ");
    Serial.print(results.bits);
    Serial.print(", decode_type is ");
    Serial.println(results.decode_type);
    irrecv.resume(); // 準備接收下一個訊號
  }
}

然後，請拿著紅外線遙控器，對著紅外線接收器隨便按一些按鈕。

我將使用Apple Remote遙控器，這是一支非常簡單的遙控器，只有六個按鈕，分別是「選單」、「播放／停止」、「音量增大」、「音量減小」、「上一個／倒退」、「下一個／快進」，可控制Mac電腦的系統音量、iTunes的音樂播放、iPhone觀賞照片幻燈片、等等。


當然了，你也可以拿其他紅外線控制器來實驗，譬如一般電視機或DVD播放機的遙控器。


應會看到類似底下的輸出：

results value is 77E11050, bits is 32, decode_type is 1

其中77E11050便是紅外線訊號的編碼，32代表它有32個位元（也就是4 bytes），而1代表它屬於哪個協定，從底下列表可知1為NEC，這些是IRRemote支援的協定。

#define NEC 1
#define SONY 2
#define RC5 3
#define RC6 4
#define DISH 5
#define SHARP 6
#define PANASONIC 7
#define JVC 8
#define SANYO 9
#define MITSUBISHI 10
#define UNKNOWN -1

我將Apple Remote遙控器六個鈕都按過之後，便能知道每個按鍵的紅外線編碼：
「選單」77E14050 、
「播放／停止」77E12050 、
「音量增大」77E1D050 、
「音量減小」77E1B050 、
「上一個／倒退」77E11050、
「下一個／快進」77E1E050。

以上是紅外線接收器的部份，接下來我要使用紅外線發射器，模擬Apple Remote遙控器的功能。

底下是接線圖，非常簡單。

Arduino的數位腳位3接100 ohm電阻後接紅外線發射器（IR LED）的長腳。

紅外線發射器的短腳接地。

注意，IRRemote限定使用數位腳位3作為紅外線訊號輸出端。若想改用其他腳位，請參考Cooper Maa的2.1 發射紅外線訊號 part 2著手修改。


程式碼如下，透過序列埠監控視窗命令紅外線發射器發出訊號：

#include <IRremote.h>

IRsend irsend; // IRRemote限定使用數位腳位3

void setup()
{
  Serial.begin(115200);
}

void loop() {
  int d;
  if( (d = Serial.read()) != -1) { // 讀取序列埠
    unsigned long v = 0x0;
    switch(d){ // 根據讀取到的資料，換成代表六個按鍵的紅外線編碼
      case '1':
        v = 0x77E14050;
      break;
      case '2':
        v = 0x77E12050;
      break;
      case '3':
        v = 0x77E1D050;
      break;
      case '4':
        v = 0x77E1B050;
      break;
      case '5':
        v = 0x77E1E050;
      break;
      case '6':
        v = 0x77E11050;
      break;
    }
   
    if(v != 0x0){
      Serial.print("read ");
      Serial.print(d);
      Serial.print(", IR send ");
      Serial.println(v, HEX);
      irsend.sendNEC(v, 32); // 輸出紅外線訊號
    }
  }
}

IRRemote函式庫支援很多種常見的紅外線協定，請使用適當的輸出函式：
void sendNEC(unsigned long data, int nbits);
void sendSony(unsigned long data, int nbits);
//  void sendSanyo(unsigned long data, int nbits); // 尚未實作
//  void sendMitsubishi(unsigned long data, int nbits); // 尚未實作
void sendRaw(unsigned int buf[], int len, int hz);
void sendRC5(unsigned long data, int nbits);
void sendRC6(unsigned long data, int nbits);
void sendDISH(unsigned long data, int nbits);
void sendSharp(unsigned long data, int nbits);
void sendPanasonic(unsigned int address, unsigned long data);
void sendJVC(unsigned long data, int nbits, int repeat);

將紅外線發射器對準我Mac電腦的紅外線接收端，啊哈，成功囉，我能透過Arduino控制音樂播放囉（雖然滿無聊的）。您可以試試家裡的遙控器，試試電源開關、頻道切換、音量增減等等按鍵。

可惜的是，因為IRRemote的限制，我們無法在一塊Arduino板子上同時加裝紅外線接收器與發射器。除非自己手動打造紅外線編解碼的功能，請參考底下的參考資料。


參考資料：

• Cooper Maa的IRRemote 紅外線遙控教學。
• Ken Shirriff's blog的A Multi-Protocol Infrared Remote Library for the Arduino。
• Adafruit Learning System的IR Sensor，介紹紅外線原理，不使用Arduino程式庫，自己撰寫函式接收與傳送紅外線訊號。
• Adafruit Learning System的Using an IR Remote with a Raspberry Pi Media Center。
• SB-Projects: IR Remote Control Theory。
• 使用紅外線遙控器搭配Arduino UNO發送控制訊號。
• GarageLab的Tutorial: Arduino IR sender and receiver。
• Instructables的Arduino IR sensor and LEDs。
• Hack a Day的Using an IR remote with your Arduino。
• 邱小新の單晶片筆記的ir remote control NEC protocol。
• 紅外線的原理與應用。