LinkIt ONE：GPS簡單試用

這一篇要試著印出GPS定位資訊，然後拿出GPS資料中的時間，設定給LDateTime。

首先裝上GPS，如下圖，板子上天線孔旁都有標示，應該不會接錯。

然後是程式碼，取自LinkIt ONE開發者手冊中的範例，稍微修改。

#include <LGPS.h>
#define BAUDRATE 19200

gpsSentenceInfoStruct info; // 儲存GPS資料
// 輔助函式，抓出資料的下一個項目
const char *nextToken(const char *src, char *buf){
  int i = 0;
  while(src[i] != 0 && src[i] != ',')
    i++;

  if(buf){
    strncpy(buf, src, i);
    buf[i] = 0;
  }

  if(src[i]){
    i++;
  }
  return src+i;  
} 
// 解析資料，印出想要的東西
void printGPGGA(const char *str)
{
  const char *p = str;
  char t[10];
  int th, tm, ts;
  char latitude[20];
  char ns[2];
  char longitude[20];
  char ew[2];
  char fixq[2];
  char n_satellite[3];
  
  p = nextToken(p, 0);      // GGA
  p = nextToken(p, t);      // Time
  th = (t[0]-'0') * 10 + (t[1]-'0');
  tm = (t[2]-'0') * 10 + (t[3]-'0');
  ts = (t[4]-'0') * 10 + (t[5]-'0');
  p = nextToken(p, latitude);  // Latitude
  p = nextToken(p, ns);      // N, S
  p = nextToken(p, longitude); // Longitude
  p = nextToken(p, ew);      // E, W
  p = nextToken(p, fixq);       // fix quality
  p = nextToken(p, n_satellite);       // number of satellites
  
  if(fixq[0] == '1'){
    Serial.print("UTC time: ");
    Serial.print(th); Serial.print(":");
    Serial.print(tm); Serial.print(":");
    Serial.println(ts);
    Serial.print("Satellite(s): ");
    Serial.println(atoi(n_satellite));
    Serial.print("Latitude: ");
    Serial.print(ns);
    Serial.println(latitude);
    Serial.print("Longitude: ");
    Serial.print(ew);
    Serial.println(longitude);
  }
  else{
    Serial.println("GPS is not fixed yet.");    
  }
} 

void setup(){
  Serial.begin(BAUDRATE);
  LGPS.powerOn();
  Serial.println("GPS power on...waiting");
  delay(3000);
}

void loop(){
  Serial.println("-------------------");
  LGPS.getData(&info);
  Serial.println((char *)info.GPGGA);
  printGPGGA((const char *)info.GPGGA);
 
  delay(10000);
}

會有很多資料，包括GPGGA（全球定位系統資料）、GPGSA（GPS精準度及可使用的衛星資訊）、GPGSV（可連結的衛星詳細資訊）、GPRMC（簡易的GPS位置資訊）等等，此篇只處理GPGGA，也只印出其中某部分。

輸出樣子如下，有UTC時間，追蹤到幾個衛星，緯度與經度。

LinkIt ONE API中有個LDateTime，只要有電源，它就會不停跳動，但必須先給它一個起跳的日期時間。而剛剛抓到的GPS資料中有UTC時間，所以把程式碼稍稍改寫如下：

#include <LGPS.h>
#include <LDateTime.h>
#define BAUDRATE 19200

gpsSentenceInfoStruct info;

const char *nextToken(const char *src, char *buf){
//...省略...
}

void printGPGGA(const char *str)
{
  //...省略...
  char n_satellite[3];
  datetimeInfo dt;
  LDateTime.setTime(&dt);
  
  p = nextToken(p, 0);      // GGA
  p = nextToken(p, t);      // Time
  th = (t[0]-'0') * 10 + (t[1]-'0');
  tm = (t[2]-'0') * 10 + (t[3]-'0');
  ts = (t[4]-'0') * 10 + (t[5]-'0');
  dt.hour = th;
  dt.min = tm;
  dt.sec = ts;
  LDateTime.setTime(&dt); // 此處只設定時間
 
  //...省略...
}
void setup(){
//...省略...}
void doit(){
  LGPS.getData(&info);
  Serial.println((char *)info.GPGGA);
  printGPGGA((const char *)info.GPGGA);
}
void loop(){
  if(Serial.available()){
    char d = Serial.read();
    switch(d){
      case 's': // 若收到's'，抓取GPS資料，並設定時間
        doit();
      break;
      case 'r':{ // 若收到'r'，從LDateTime拿到時間並印出
        datetimeInfo dt;
        LDateTime.getTime(&dt);
        Serial.print(dt.hour); Serial.print(":");
        Serial.print(dt.min); Serial.print(":");
        Serial.println(dt.sec);
      }
      break;
    }
  }
}

輸出如下：

不知道為什麼，LDateTime的時間會落後於GPS的時間，而且似乎越差越遠；但程式中明明每次抓取GPS資料時，都會再次設定，卻好像無作用似的，真奇怪。