Arduino Yún：範例草稿碼Bridge、從瀏覽器操控腳位

這一篇玩玩Bridge程式庫裡的BridgeServer（舊稱YunServer）與BridgeClient（舊稱YunClient）這兩個類別，程式碼主要都來自於Arduino官方範例草稿碼Bridge。

我的Yún與開發主機位於同一個區域網路內，我的Arduino軟體開發環境是1.6.7版。首先從瀏覽器登入Yún，開啟REST API存取權限為OPEN。

底下是範例程式碼，這支程式碼的功能是讓我們從別台電腦的瀏覽器控制Arduino的腳位。

#include <Bridge.h>
#include <BridgeServer.h>
#include <BridgeClient.h>

// Yún的網站伺服器，會把所有HTTP請求（/arduino）轉送給BridgeServer
BridgeServer server; // 預設會聆聽連接埠5555

void setup() {
    Serial.begin(57600);
    while(!Serial && millis() < 9000){
    }
   
    Serial.print("Starting Bridge...");
    Bridge.begin();
    Serial.println("done.");

    // 只接受從localhost來的連線
    server.listenOnLocalhost();
    server.begin();
}

void loop() {
    // 不斷呼叫accept，檢查是否有連線
    BridgeClient client = server.accept();

    // 若client有值，代表有連線
    if(client){
        process(client); // 處理請求
        client.stop(); // 關閉連線，也會釋放掉相關資源
    }

    delay(50); // 暫停50毫秒
}

void process(BridgeClient client) {
    // 讀取URL網址
    String command = client.readStringUntil('/');

    // 判斷，做該做的事情
    if(command == "digital"){
        digitalCommand(client);
    }
    else if(command == "analog"){
        analogCommand(client);
    }
    else if(command == "mode"){
        modeCommand(client);
    }
}

void digitalCommand(BridgeClient client){
    int pin, value;

    pin = client.parseInt(); // 哪個腳位
   
    if(client.read() == '/'){ // 若下個字元是'/'
        // 代表這個URL應會類似於"/digital/13/1"，要寫入
        value = client.parseInt();
        digitalWrite(pin, value);
    }
    else{ // 若不是，則是讀取
        value = digitalRead(pin);
    }

    // 回送回應給瀏覽器
    client.print(F("Pin D"));
    client.print(pin);
    client.print(F(" set to "));
    client.println(value);

    // 把腳位狀態儲存在內部的鍵值配對空間
    String key = "D";
    key += pin;
    Bridge.put(key, String(value));
}

void analogCommand(BridgeClient client) {
    int pin, value;

    pin = client.parseInt();

    if(client.read() == '/'){
        value = client.parseInt();
        analogWrite(pin, value);

        client.print(F("Pin D"));
        client.print(pin);
        client.print(F(" set to analog "));
        client.println(value);

        String key = "D";
        key += pin;
        Bridge.put(key, String(value));
    }
    else{
        value = analogRead(pin);

        client.print(F("Pin A"));
        client.print(pin);
        client.print(F(" reads analog "));
        client.println(value);

        String key = "A";
        key += pin;
        Bridge.put(key, String(value));
    }
}

void modeCommand(BridgeClient client) {
    int pin = client.parseInt();

    // 下個字元必須是'/'
    if (client.read() != '/') {
        client.println(F("error"));
        return;
    }

    String mode = client.readStringUntil('\r');

    if(mode == "input"){
        pinMode(pin, INPUT);
       
        client.print(F("Pin D"));
        client.print(pin);
        client.print(F(" configured as INPUT!"));
    }
    else if(mode == "output"){
        pinMode(pin, OUTPUT);
       
        client.print(F("Pin D"));
        client.print(pin);
        client.print(F(" configured as OUTPUT!"));
    }
    else{
        client.print(F("error: invalid mode "));
        client.print(mode);
    }
}

然後從別台電腦的瀏覽器，輸入類似底下的網址，請把arduino.local換成你的Yún的IP位址。當Yun看到網址「/arduino」時，不會做什麼處理，都會轉交給草稿碼（ATmega32U4）。

把腳位13設為輸出模式：
http://arduino.local/arduino/mode/13/output
瀏覽器上會看到回應：
Pin D13 configured as OUTPUT!

把腳位13設為高電位，其連接的LED會亮起：
http://arduino.loca/arduino/digital/13/1
瀏覽器上會看到回應：
Pin D13 set to 1

把腳位13設為低電位，其連接的LED會熄滅：
http://arduino.loca/arduino/digital/13/0
瀏覽器上會看到回應：
Pin D13 set to 0

腳位3輸出PWM128：
http://arduino.loca/arduino/analog/3/128
瀏覽器上會看到回應： 
Pin D3 set to analog 128

讀取類比腳位A0（對應腳位編號18）的值：
http://arduino.loca/arduino/analog/18
瀏覽器上類似底下的回應：
Pin A18 reads analog 253


參考資料：

• Arduino官方文件，Guide to the Arduino Yún、BridgeServer類別與BridgeClient類別。