Arduino Yún：Bridge程式庫入門之Console

Yún除了有微控制器ATmega32U4（跟Leonardo相同），還有一顆Atheros AR9331，運行Linux發行套件OpenWRT-Yun（以OpenWRT為基礎修改而成），這顆晶片連接到乙太網路（Ethernet）、Wi-Fi無線網路、板子上的USB A埠（主方）與micro SD記憶卡插槽。

當我們撰寫ATmega32U4的草稿碼時，可透過Bridge程式庫來跟OpenWRT-Yun溝通，使用各種功能。請看官方網站提供的架構示意圖。

（呃，arduino.cc不是改成OpenWRT-Yun了嗎，怎麼還留著Linino的字樣。）

Bridge程式庫裡有許多類別，分別對應各種功能包括Bridge、Console、Process、FileIO、Mailbox、HttpClient、YunClient（也叫BridgeClient）與YunServer（也叫BridgeServer）。其原始碼都在Arduino軟體開發環境安裝目錄\libraries\Bridge\底下。

接下來嘗試使用Console，底下的程式碼大部分都是從Arduino官方網站與軟體開發環境提供的範例修改而來。

顧名思義，Console的作用類似於主控台、終端機的功能，跟以前的序列埠很像，但現在可經由Wi-Fi無線登入。

底下這支程式會從Console接收資料，若收到字元H就點亮板子上內建的LED，若收到字元L就熄滅。

#include <Console.h>
#define LED_PIN 13
void setup() {
  Bridge.begin(); // 啟動Bridge，其他類別都需要它
  Console.begin(); // 初始化Console

  while(!Console){ // 等待開啟Console
  } 

  if(Console.connected()){
    Console.println("Console is connected");
  }
  Console.println("type H or L to turn pin 13 on or off");

  pinMode(LED_PIN, OUTPUT);
}
void loop() {
    if(Console.available() > 0){
        char b = (char) Console.read();
      
        if(b == 'H'){
            Console.println(b);
            digitalWrite(LED_PIN, HIGH);
        }
        else if(b == 'L'){
            Console.println(b);
            digitalWrite(LED_PIN, LOW);
        }
        else if(b == '\n' || b == '\r'){
        }
        else{
            Console.println("type H or L to turn pin 13 on or off");
        }
    }
}

Console類別本身，用起來就跟Serial差不多。然後可從選單「工具」-「序列埠」選擇「Arduino at xxx.xxx.xxx.xx (Arduino Yún)」，此時開啟序列埠監控視窗的話，便可連接Yún的Console，畫面如下。

似乎有點複雜，搞不清楚哪個是哪個，簡單關係示意圖如下：

主機電腦的Arduino IDE的序列埠監控視窗-經由網路連線-Yun的Linux（OpenWRT-Yun）-再到Yun的微控制器（ATmega32U4）的草稿碼

也可自己透過SSH登入Console，請把arduino.local換成你的Yún的IP位址。

$ ssh root@arduino.local
root@arduino.local's password:
...省略...

登入後，下指令連接Console，如下：

root@Arduino:~# telnet localhost 6571
Console is connected
type H or L to turn pin 13 on or off

然後就可以輸入H或L控制LED亮滅。（上述指令可合併成$ ssh root@arduino.local 'telnet localhost 6571'）

然後是Process，可要求執行某程式或Linux指令，底下程式碼會執行uptime指令，得知系統開機後已經過多少時間，然後執行curl，取回以ASCII畫出來的Arduino logo。

#include <Process.h>

void setup() {
    Bridge.begin();
    Serial.begin(56700);

    while(!Serial)
        ;

    run_uptime();
    run_curl();
}
void loop() {
}

void run_curl() {
    Process p;
    p.begin("curl"); // Linux指令
    p.addParameter("http://arduino.cc/asciilogo.txt"); // 加上參數
    p.run(); // 執行，這是阻斷式方法，執行結束後才會回傳

    while(p.available() > 0){ // 將指令執行結果送往序列埠監控視窗
        char c = p.read();
        Serial.print(c);
    }
    Serial.flush();
}

void run_uptime(){
    Process p;
    p.begin("uptime");
    p.run();

    while(p.available() > 0){
        char c = p.read();
        Serial.print(c);
    }
    Serial.flush();
}

結果如下圖：

對Bridge程式庫有基本了解後，就可以開始玩玩其他更進階的類別，諸如YunServer、YunClient、HttpClient、MailBox、等等。


參考資料：

• Arduino官方文件的ArduinoYun與Bridge Library for Arduino Yún。
• Arduino官方部落格Hands on: the Arduino Yún’s Bridge。